Summary Files Commits Branches @commit @diff @stats
path: root / awk-edits
diff options
context:
space:
mode:
Commit0187e255a811bebb0dad3624f2c6d78b829d15c5 (patch)
Author
 Syndamia <kamen@syndamia.com>
2023-01-17 16:15:28 +0200
Committer
 Syndamia <kamen@syndamia.com>
2023-01-17 16:15:28 +0200
Files68efd3520e72c8c8c553fdda7b9391d9ec4e9feb /awk-edits
syndamia.com-0187e255a811bebb0dad3624f2c6d78b829d15c5.tar
syndamia.com-0187e255a811bebb0dad3624f2c6d78b829d15c5.tar.gz
syndamia.com-0187e255a811bebb0dad3624f2c6d78b829d15c5.zip
Parentda000c477625bb533688df84bd95ba3a3aff3246 (diff)
[awk] Reworked generation to happen via a combined script, updated scripts and added info in scripts readme
11 files changed, 501 insertions, 0 deletions
-rw-r--r--awk-edits/File-lists.awk165
-rw-r--r--awk-edits/Flags.awk30
-rw-r--r--awk-edits/Group-contents.awk20
-rw-r--r--awk-edits/Header-Title.awk26
-rw-r--r--awk-edits/Header-description.awk36
-rw-r--r--awk-edits/Heading-anchors.awk12
-rw-r--r--awk-edits/Pagenav.awk39
-rw-r--r--awk-edits/Presentation.awk141
-rw-r--r--awk-edits/README.md25
-rw-r--r--awk-edits/_print.awk3
-rw-r--r--awk-edits/post-pagenav.awk4
diff --git a/awk-edits/File-lists.awk b/awk-edits/File-lists.awk
new file mode 100644
index 0000000..8903b95
--- /dev/null
+++ b/awk-edits/File-lists.awk
@@ -0,0 +1,165 @@
+#
+# == About ==
+#
+# Each file list is a "details" element, that contains a table, each row being a different file
+# or alternatively, just the table on it's own.
+#
+# -- Result HTML --
+#
+# <details>
+# <summary>Folder Info</summary>
+# <table>
+# <tr>File Data</tr>
+# </table>
+# </details>
+# or
+# <table>
+# <tr>File Data</tr>
+# </table>
+
+#
+# == ftags ==
+#
+# &&folder The text right afterwards is the title of the folder. All files
+# are hidden inside the collapsed details tag (click to show).
+# The file table is indented. You cannot have a folder inside a folder.
+# It can be omitted, and the files table will be shown as-is.
+#
+# &&file Everything that follows this tag is the data for a file. You should
+# use &&fd to specify columns of information! Depending on the context,
+# it might be flrepllaced with the start of a table, closing the summary
+# and starting table, or closing and opening a table row.
+#
+# &&/files This tag must exist at the bottom of a file list, no matter if it was
+# started with or without a &&folder.
+#
+# &&fd Defines a column of information for a file (row). Practically, it is
+# flrepllaced with <td>, and </td> is added to the end of the line.
+# If you don't use it, make sure to have the leading and trailing td tags!
+#
+# &&ft-TYPE Depending on TYPE, it inserts an image tag that contains the file "icon"
+# for the corresponding type.
+# Available values for TYPE: photo, text, zip, movie, markdown
+#
+# -- Placement/Flow --
+#
+# All ftags, except &&fd, can be placed on their own line (empty line above and below)
+# or before/after another ftag.
+# Folder title must be inside the same paragraph as the ftag itself. This means that,
+# after
+# every &&folder ftag, the text can continue directly next to it and/or on new lines,
+# without there being any empty lines (you can add those with <br> or two spaces at
+# line end).
+#
+# -- Example Usage --
+#
+# (I like to indent a bit &&fd ftags, for readability's sake, but you don't have to)
+#
+# &&file
+# &&ft-text
+# &&fd Notes
+# &&fd 10 KB
+# &&/files
+#
+# &&folder Math
+# &&file
+# &&ft-text
+# &&fd Homework 1
+# &&file
+# &&ft-text
+# &&fd Homework 2
+# &&/files
+#
+# &&folder Art Project<br>
+# Status: 70% complete<br>
+# Note: Reserach Van Gogh paintings
+#
+# &&file
+# &&fd Painting 1
+# &&fd 100% Complete
+#
+# &&file
+# &&fd Painting 2
+# &&fd 40% Complete
+#
+# &&/files
+
+BEGIN {
+ fileStarted = 0
+ noFolder = 1
+ searchEndP = 0 # Used to remove trailing </p> in file row
+
+ # Special formatting
+ flname[1] = "folder"
+ flrepl[1] = "<details class=\"file-wrapper\"><summary>"
+ flname[2] = "file"
+ flrepl[2] = "</tr><tr>"
+ flname[3] = "&#47;files" # /files
+ flrepl[3] = "</tr></table></details>"
+ flname[4] = "fd"
+ flrepl[4] = "" # Not used, refer to fileSubstitute function
+
+ flname[5] = "ft-photo"
+ flrepl[5] = "photo-tabler.svg"
+ flname[6] = "ft-text"
+ flrepl[6] = "file-text-tabler.svg"
+ flname[7] = "ft-zip"
+ flrepl[7] = "file-zip-tabler.svg"
+ flname[8] = "ft-movie"
+ flrepl[8] = "movie-tabler.svg"
+ flname[9] = "ft-markdown"
+ flrepl[9] = "markdown-tabler.svg"
+
+ for (i = 1; i <= length(flname); i++) {
+ flpat[i] = "&#38;&#38;" flname[i]
+ if (index(flname[i], "ft") == 1)
+ flrepl[i] = "<td><img class=\"file-icon unzoomable\" src=\"/img/" flrepl[i] "\"></td>"
+ }
+}
+
+function fileSubstitute(ind) {
+ gsub(/(<p>|<\/p>)/, "")
+
+ # &&file
+ if (ind == 2 && fileStarted == 0) {
+ if (noFolder == 1)
+ gsub("&#38;&#38;file", "<table class=\"file-list\"><tr>")
+ else
+ gsub("&#38;&#38;file", "</summary><table class=\"file-list\"><tr>")
+ fileStarted = 1
+ }
+ # &&/files
+ else if (ind == 3 && noFolder == 1) {
+ gsub("&#38;&#38;&#47;files", "</tr></table>")
+ }
+ # &&fd
+ else if (ind == 4) {
+ gsub(/&#38;&#38;fd[ \t]*/, "<td>")
+ gsub(/$/, "</td>")
+ }
+ else
+ gsub(flpat[ind], flrepl[ind])
+
+ # &&folder
+ if (ind == 1) {
+ noFolder = 0
+ searchEndP = 1
+ }
+ # &&/files
+ else if (ind == 3) {
+ fileStarted = 0
+ noFolder = 1
+ }
+}
+
+/^[ \t]*(<p>|)&#38;&#38;/ {
+ for (i = 1; i <= length(flname); i++) {
+ if (index($0, flpat[i]) != 0)
+ fileSubstitute(i)
+ }
+}
+
+searchEndP == 1 && /<\/p>/ {
+ gsub(/<\/p>/, "")
+ searchEndP = 0
+}
diff --git a/awk-edits/Flags.awk b/awk-edits/Flags.awk
new file mode 100644
index 0000000..6f62916
--- /dev/null
+++ b/awk-edits/Flags.awk
@@ -0,0 +1,30 @@
+#
+# == About ==
+#
+# A collection of ftags that generate an image HTML tag, containing the specified
+# flag. This is done, because these tags need to have the unzoomable class, which
+# you can't specify in Markdown.
+
+# == ftags ==
+#
+# &&gb Great Britain flag
+#
+# -- Placement/Flow --
+#
+# They can reside absolutely anywhere in text.
+
+BEGIN {
+ flag[1] = "gb"
+ flagTitle[1] = "ENG"
+
+ for (i = 1; i <= length(flag); i++) {
+ flagExp[i] = "&#38;&#38;" flag[i]
+ flagTag[i] = "<img src=\"/img/" flag[i] ".svg\" class=\"unzoomable svg\" alt=\"" flagTitle[i] "\" flagTitle=\"" flagTitle[i] "\">"
+ }
+}
+
+{
+ for (i = 1; i <= length(flagExp); i++) {
+ gsub(flagExp[i], flagTag[i])
+ }
+}
diff --git a/awk-edits/Group-contents.awk b/awk-edits/Group-contents.awk
new file mode 100644
index 0000000..d984eef
--- /dev/null
+++ b/awk-edits/Group-contents.awk
@@ -0,0 +1,20 @@
+#
+# == About ==
+#
+# This script surrounds the "Contents" heading, as well as the list itself, in a div wrapper element
+# For it to work properly, the contents heading must be h2 and have it's id as "contents",
+# and there must be a paragraph element after the item list
+
+BEGIN {
+ started = 0
+}
+
+/h2 id="contents"/ {
+ print "<div id=\"contents-container\">"
+ started = 1
+}
+
+started == 1 && /<p>/ {
+ print "</div>"
+ started = 0
+}
diff --git a/awk-edits/Header-Title.awk b/awk-edits/Header-Title.awk
new file mode 100644
index 0000000..16247e8
--- /dev/null
+++ b/awk-edits/Header-Title.awk
@@ -0,0 +1,26 @@
+#
+# == About ==
+#
+# Every page has a og:title meta tag, which has to be generated from the page
+# itself. The title tag is automatically filled in by ssg.
+# The value for the meta tag is "[TITLE]" and it gets replaced with all text
+# inside first h1 header tag.
+
+BEGIN {
+ h1Index = 0
+
+ # When this loop finishes, $0 will have the first line containing an h1 header
+ # tag, and h1Index will have it's starting position
+ while (h1Index == 0 && getline < ARGV[1])
+ h1Index = index($0, "<h1")
+ close(ARGV[1]) # FILENAME isn't set during BEGIN
+
+ # Removes the opening tag and substrings everything that is normally
+ # inside the heading tag
+ gsub(/<h1[^>]*>/, "")
+ title = substr($0, h1Index, index($0, "</h1") - h1Index)
+}
+
+"\\[TITLE\\]" {
+ gsub("\\[TITLE\\]", title)
+}
diff --git a/awk-edits/Header-description.awk b/awk-edits/Header-description.awk
new file mode 100644
index 0000000..028c14c
--- /dev/null
+++ b/awk-edits/Header-description.awk
@@ -0,0 +1,36 @@
+#
+# == About ==
+#
+# Every page has a description and og:description meta tags. These descriptions
+# are generated from the paragraphs, inside the given page.
+# The value for those meta tags is "[DESCRIPTION]" and it gets replaced with
+# either all of the text on the page, or only the first 200 characters.
+
+function appToDesc(l) {
+ gsub(/<[^>]*>/, "", l) ; gsub("&#8217;", "'", l)
+ gsub(/[^a-zA-Z0-9 '.]/, "", l)
+ gsub(/^[ \t]*/, "", l) ; gsub(/[ \t]*$/, "", l)
+
+ desc = desc l
+ if (length(desc) >= 200) {
+ desc = substr(desc, 1, 197) "..."
+ return 1
+ }
+ return 0
+}
+
+BEGIN {
+ stop = 0
+
+ # Loop over the whole file, extract all text in first couple of paragraphs,
+ # store it in desc (but no more than 200 characters will be saved)
+ while(stop == 0 && getline < ARGV[1]) {
+ if (index($0, "<p") > 0)
+ stop = appToDesc($0)
+ }
+ close(ARGV[1]) # FILENAME isn't set during BEGIN
+}
+
+"\\[DESCRIPTION\\]" {
+ gsub("\\[DESCRIPTION\\]", desc)
+}
diff --git a/awk-edits/Heading-anchors.awk b/awk-edits/Heading-anchors.awk
new file mode 100644
index 0000000..e4367c7
--- /dev/null
+++ b/awk-edits/Heading-anchors.awk
@@ -0,0 +1,12 @@
+#
+# == About ==
+#
+# ssg generates an id for every heading. That's why after every heading there
+# can be a hyperlink to itself. However, because of the current styling, such a
+# hyperlink is required (except for h1).
+
+/[ \t]*<h[23456]/ {
+ id = substr($0, index($0, "id=\"") + 4)
+ id = substr(id, 0, index(id, "\"") - 1)
+ gsub(/$/, ORS "<a class=\"h-anchor\" href=\"#" id "\"><img src=\"/img/link-tabler.svg\" alt=\"🔗\" loading=\"lazy\"></a>")
+}
diff --git a/awk-edits/Pagenav.awk b/awk-edits/Pagenav.awk
new file mode 100644
index 0000000..46589fb
--- /dev/null
+++ b/awk-edits/Pagenav.awk
@@ -0,0 +1,39 @@
+#
+# == About ==
+#
+# I call pagenav the stuff directly below the first h1. These include file dates
+# and GitLab source link.
+# Currently it only works for blog and tutorial pages.
+#
+# This is by far the most hard-coded and inefficient awk script in the generate-hooks.
+# Creation and last edited dates are taken from git commits, and getting the correct info
+# by file name can easily only be done with git log, which unfortunately is very slow.
+# Another issue is that it depends on the build directories in build scripts, meaning
+# it won't work without modification if you try to build it somewhere else.
+
+BEGIN {
+ fileCheck = ARGV[1] # FILENAME isn't available in BEGIN
+
+ if (match(fileCheck, /(blog|tutorials)\/.*\//) == 0) {
+ found = 1
+ }
+ else {
+ found = 0
+ gsub(/^.*\/(synd|tiny.synd|website|tiny.website)\//, "", fileCheck); gsub(/\.html/, ".md", fileCheck)
+
+ system("git log --follow --pretty=format:%ad --date=\"format:%d %B %Y\" -- src/" fileCheck " > /tmp/syndamiadotcom-pagenav")
+
+ dateCreate = ""
+ dateEdited = ""
+ while ((getline < "/tmp/syndamiadotcom-pagenav") > 0) {
+ if (dateEdited == "") dateEdited = $0
+ dateCreate = $0
+ }
+
+ elem = ORS \
+"<div id=\"pagenav\">" ORS \
+" <strong>Created: " dateCreate "</strong> || <strong>Edited: " dateEdited "</strong>" ORS \
+" || <a href=\"https://gitlab.com/Syndamia/syndamiadotcom/-/blob/master/src/" fileCheck "\"><strong>GitLab source</strong></a>" ORS \
+"</div>"
+ }
+}
diff --git a/awk-edits/Presentation.awk b/awk-edits/Presentation.awk
new file mode 100644
index 0000000..f0bbb4a
--- /dev/null
+++ b/awk-edits/Presentation.awk
@@ -0,0 +1,141 @@
+#
+# == About ==
+#
+# This is my way of making slide-based presentations. In short, it just groups
+# Markdown formatting into rectangles and adds options for layout formatting.
+# Each slide is the size of a landscape-oriented A4 sheet of paper. Light/dark
+# mode settings are respected (of course).
+# Currently, this appliest only to pages under the "talks" folder.
+
+#
+# == ftags ==
+#
+# &&presentation Must appear before any other presentation ftags.
+# It "loads" everything necessary for a presentation, that being
+# the navigation bar and logic script (which also inserts the
+# custom stylesheet).
+# Can be only one per page. Also refer to -- Surroundings --
+#
+# &&slide Everything below this tag is part of a slide. Each slide is
+# presented in the order it appears in.
+# &&/slide Ends (the last started) slide.
+#
+# &&frow A row of paragraphs, where each item is evenly sized and is
+# spaced out horizontally. In the HTML, it is a simple flexbox.
+# This is one of the two main ways to configure how content is
+# laid out on a slide.
+# &&/frow Every HTML element/paragraph between &&frow and &&/frow is an
+# item that will be laid out.
+#
+# &&fcol A column of paragraphs, where each item is evenly sized and is
+# spaced out vertically. In the HTML, it is a simple flexbox.
+# This is one of the two main ways to configure how content is
+# laid out on a slide.
+# &&/fcol Every HTML element/paragraph between &&fcol and &&/fcol is an
+# item that will be laid out.
+#
+# &&flexer An empty container, which can be used as a blank space item
+# inside &&frow or &&fcol. In the styling, it just has `flex: 1`.
+#
+# &&centered Aligns text to the center, literally.
+# &&/centered Text between &&centered and &&/centered is aligned.
+#
+# &&fright Aligns element and the text inside to the right. In the styling,
+# it just has text-align and float set to right.
+# &&/fright Text between &&fright and &&/fright is aligned to the right
+#
+# &&fontSIZE Changes to font size to SIZE, in pixels. Default size is 24px.
+# Available values for SIZE: 18, 20, 27, 30, 37
+# &&/font Text between &&fontSIZE and &&/font is sized accordingly
+#
+# -- Surroundings --
+#
+# As stated, there can only be one presentation per page.
+# Everything that is around a presentation and it's slides is normally hidden
+# during presenting mode, but will show up if you try to print the presentation.
+# Exceptions to this rule are headings and paragraphs, which won't show up in
+# presenting mode or during print.
+#
+# -- Placement/Flow --
+#
+# All ftags can be placed on their own line, or in a line with other ftags.
+# The only requirement is that such a line must start with an ftag, ftags in the
+# middle of text aren't recognized.
+#
+# -- Example Usage --
+#
+# Refer to src/talks/demo.md
+
+BEGIN {
+ nopresentation=substr(ARGV[1], "talks") == 0 # FILENAME isn't available yet
+
+ # Exceptions to the normal format
+ names[ 1] = "presentation"
+ ended[ 1] = 0
+ names[ 2] = "&#47;font" # all font ftags can be closed with a &&/font
+ ended[ 2] = 0
+
+ names[ 3] = "slide"
+ ended[ 3] = 1
+ names[ 4] = "centered"
+ ended[ 4] = 1
+ names[ 5] = "flexer"
+ ended[ 5] = 2
+ names[ 6] = "frow"
+ ended[ 6] = 1
+ names[ 7] = "fcol"
+ ended[ 7] = 1
+ names[ 8] = "font18"
+ ended[ 8] = 0
+ names[ 9] = "font20"
+ ended[ 9] = 0
+ names[10] = "font27"
+ ended[10] = 0
+ names[11] = "font30"
+ ended[11] = 0
+ names[12] = "font35"
+ ended[12] = 0
+ names[13] = "fright"
+ ended[13] = 1
+
+ pres = ORS \
+"<nav id=\"presentCont\">" ORS \
+" <img id=\"prevSlideBtn\" class=\"unzoomable btn setting-btn icon nodisplay\" src=\"/img/arrow-left-tabler.svg\" alt=\"Previous\">" ORS \
+" <img id=\"nextSlideBtn\" class=\"unzoomable btn setting-btn icon nodisplay\" src=\"/img/arrow-right-tabler.svg\" alt=\"Next\">" ORS \
+" <img id=\"presentBtn\" class=\"unzoomable btn setting-btn icon\" src=\"/img/presentation-tabler.svg\" alt=\"Present\">" ORS \
+" <img id=\"printBtn\" class=\"unzoomable btn setting-btn icon\" src=\"/img/printer-tabler.svg\" alt=\"Print\">" ORS \
+" </nav>" ORS \
+" <script type=\"text/javascript\" src=\"/scripts/presentation.js\" integrity=\"sha512-5u+Yy4xqrGKYXeUrzgaXXj7dqNtFUnlaPtfz86v9nT+l8osWfLnjLOU/vRv2Hmx7wsmCdb3pfurH0/hQHLQOSA==\" crossorigin=\"anonymous\"></script>"
+
+ pat[1] = "&#38;&#38;presentation"
+ rep[1] = pres
+ pat[2] = "&#38;&#38;&#47;font"
+ rep[2] = "</div>"
+
+ for (i = 3; i <= length(names); i++) {
+ pat[i] = "&#38;&#38;" names[i]
+ rep[i] = "<div class=\"" names[i] "\">"
+
+ if (ended[i] == 1) {
+ cpat[i] = "&#38;&#38;&#47;" names[i]
+ crep[i] = "</div>"
+ }
+ else if (ended[i] == 2) {
+ rep[i] = rep[i] "</div>"
+ }
+ }
+}
+
+function presentationSubstitute(ind) {
+ gsub(/(<p>|<\/p>)/, "")
+ gsub(pat[ind], rep[ind])
+ if (ended[ind] == 1)
+ gsub(cpat[ind], crep[ind])
+}
+
+nopresentation == 0 && /^[ \t]*(<p>|)&#38;&#38;/ {
+ for (i = 1; i <= length(names); i++) {
+ if (index($0, names[i]) != 0)
+ presentationSubstitute(i)
+ }
+}
diff --git a/awk-edits/README.md b/awk-edits/README.md
new file mode 100644
index 0000000..a9d1c77
--- /dev/null
+++ b/awk-edits/README.md
@@ -0,0 +1,25 @@
+All `.awk` files in this folder are ran by `generate.sh` and `generate-dev.sh`, after ssg and lowdown have created all HTML pages. These files are meant to work on the resultant HTML.
+
+For improved efficiency, rather than running every script seperately, they are meant to be concatinated into one script (`generate.sh` and `generate-dev.sh` combine them in `/tmp/syndamiadotcom-awk`), which is ran for each HTML file.
+This forces us to work with the following constraints:
+
+- NO awk script should print the current line (print should only be used to add new lines)
+ The script that starts with '\_' contains the print of the current line, all scripts that start with a capital letter are ran before it and all with small letter - after.
+ + If we print the current line in every script, the concatenated will print the current line multiple times
+- Variable names between scripts must be unique
+- `exit` mustn't be used!
+ Instead, use a variable and then add a check to every relevant rule.
+
+## ftags
+
+ftags are strings/words in the Markdown source files, that start with "&&" and continue with any (valid) sequence of characters. The name initially stood for "file tags", since I got the idea while making the file lists functionality. Now I like to think of them as "format tags", since they are used for so much more.
+
+On the "backend", they just get replaced with specific HTML. List of scripts that handle ftags:
+
+|Script|ftags|
+|---|---|
+|`File-lists.awk`|`&&folder`, `&&file`, `&&/files`, `&&ft-TYPE` *(TYPE is one of `photo`, `text`, `zip`, `movie`, `markdown`)*|
+|`Flags.awk`|`&&gb`|
+|`Presentation.awk`|`&&presentation`, `&&slide`, `&&/slide`, `&&flexer`, `&&centered`, `&&/centered`, `&&fow`, `&&/fow`, `&&fcol`, `&&/fcol`, `&&fontSIZE` *(SIZE is one of `18`, `20`, `27`, `30`, `37`)*, `&&/font`|
+
+Information regarding their usage can be found at the top of their respective script file.
diff --git a/awk-edits/_print.awk b/awk-edits/_print.awk
new file mode 100644
index 0000000..fcf69c6
--- /dev/null
+++ b/awk-edits/_print.awk
@@ -0,0 +1,3 @@
+{
+ print
+}
diff --git a/awk-edits/post-pagenav.awk b/awk-edits/post-pagenav.awk
new file mode 100644
index 0000000..4587cae
--- /dev/null
+++ b/awk-edits/post-pagenav.awk
@@ -0,0 +1,4 @@
+found == 0 && /<h1.*/ {
+ print elem
+ found = 1
+}