Website Summary Files Commits Branches @commit @diff @stats
path: root / homework / 81030 / rust2html.flex
blob: 6684d825d9aa3704535290f7a9f06ffae58d62be (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
/* scanner for the Rust programming language */

%{
#define YY_NO_UNISTD_H
%}

NONEOL_CHAR        [^\n]
DEC_DIGIT          0|{NONZERO_DEC_DIGIT}
NONZERO_DEC_DIGIT  [1-9]
OCT_DIGIT          [0-7]
HEX_DIGIT          {DEC_DIGIT}|[a-fA-F]

IDENTIFIER             {IDENTIFIER_FIRST_CHAR}({DEC_DIGIT}|{IDENTIFIER_FIRST_CHAR})*
IDENTIFIER_FIRST_CHAR  [A-Za-z_]

COMMENT        {BLOCK_COMMENT}|{LINE_COMMENT}
BLOCK_COMMENT  "/*".*"*/"
LINE_COMMENT   "//"{NONEOL_CHAR}*

KEYWORD  _|abstract|alignof|as|become|box|break|const|continue|crate|do|else|enum|extern|false|final|fn|for|if|impl|in|let|loop|macro|match|mod|move|mut|offsetof|override|priv|proc|pub|pure|ref|return|Self|self|sizeof|static|struct|super|trait|true|type|typeof|unsafe|unsized|use|virtual|where|while|yield

ESCAPE          {COMMON_ESCAPE}|{UNICODE_ESCAPE}
COMMON_ESCAPE   \\|n|r|t|0|x{HEX_DIGIT}{2}
UNICODE_ESCAPE  "u{"{HEX_DIGIT}{6}"}"

CHAR_LITERAL         '{CHAR_BODY}'
CHAR_BODY            [^']|(\\('|{ESCAPE}))
STRING_LITERAL       \"{STRING_BODY}*\"
STRING_BODY          [^\"]|(\\(\"|{ESCAPE}))
BYTE_CHAR_LITERAL    b'{BYTE_CHAR_BODY}'
BYTE_CHAR_BODY       [^']|(\\('|{COMMON_ESCAPE}))
BYTE_STRING_LITERAL  b\"{BYTE_STRING_BODY}*\"
BYTE_STRING_BODY     [^\"]|(\\(\"|{ESCAPE}))

NUMBER_LITERAL     {NONZERO_DEC_DIGIT}{DEC_DIGIT}*{FLOAT_SUFFIX}?|(0{DEC_DIGIT_LITERAL}*{FLOAT_SUFFIX}?|b[10_]+|o{OCT_DIGIT_LITERAL}+|x{HEX_DIGIT_LITERAL}+)
FLOAT_SUFFIX       {EXPONENT}|"."{DEC_DIGIT_LITERAL}+{EXPONENT}?
EXPONENT           [Ee][-+]?{DEC_DIGIT_LITERAL}+
DEC_DIGIT_LITERAL  {DEC_DIGIT}|_
HEX_DIGIT_LITERAL  {HEX_DIGIT}|_
OCT_DIGIT_LITERAL  {OCT_DIGIT}|_

SYMBOL  "::"|"->"|"#"|"["|"]"|"("|")"|"{"|"}"|","|";"

%%

{SYMBOL} {
    printf("<span class=\"symbol\">%s</span>", yytext);
}

{KEYWORD} {
    printf("<span class=\"keyword\">%s</span>", yytext);
}

{NUMBER_LITERAL} {
    printf("<span class=\"number\">%s</span>", yytext);
}

{IDENTIFIER} {
    printf("<span class=\"identifier\">%s</span>", yytext);
}

{CHAR_LITERAL}|{STRING_LITERAL}|{BYTE_CHAR_LITERAL}|{BYTE_STRING_LITERAL} {
    printf("<span class=\"string\">%s</span>", yytext);
}

{COMMENT} {
    printf("<span class=\"comment\">%s</span>", yytext);
}

. {
    printf("%s", yytext);  /* echo the rest */
}

%%

int yywrap() {
    return 1;
}

int main(int argc, const char* argv[]) {
    yyin = argc > 1 ? fopen(argv[1], "r") : stdin;

    puts(
        "<!DOCTYPE html>"
        "<html>"
        "<head>"
        "    <style>"
        "        .comment {"
        "            color: gray;"
        "        }"
        "        .keyword {"
        "            color: red;"
        "        }"
        "        .string {"
        "            color: green;"
        "        }"
        "        .number {"
        "            color: blue;"
        "        }"
        "        .symbol {"
        "            font-weight: bold;"
        "        }"
        "    </style>"
        "</head>"
        "<body>"
        "    <pre class=\"code\">"
    );
    yylex();
    puts(
        "    </pre>"
        "</body>"
        "</html>");

    return 0;
}