/*
*  cool.y
*              Parser definition for the COOL language.
*
*/
%{
  #include <iostream>
  #include "cool-tree.h"
  #include "stringtab.h"
  #include "utilities.h"
  
  extern char *curr_filename;
  
  
  /* Locations */
  #define YYLTYPE int              /* the type of locations */
  #define cool_yylloc curr_lineno  /* use the curr_lineno from the lexer
  for the location of tokens */
    
    extern int node_lineno;          /* set before constructing a tree node
    to whatever you want the line number
    for the tree node to be */
      
      
      #define YYLLOC_DEFAULT(Current, Rhs, N)         \
      Current = Rhs[1];                             \
      node_lineno = Current;
    
    
    #define SET_NODELOC(Current)  \
    node_lineno = Current;
    
    /* IMPORTANT NOTE ON LINE NUMBERS
    *********************************
    * The above definitions and macros cause every terminal in your grammar to 
    * have the line number supplied by the lexer. The only task you have to
    * implement for line numbers to work correctly, is to use SET_NODELOC()
    * before constructing any constructs from non-terminals in your grammar.
    * Example: Consider you are matching on the following very restrictive 
    * (fictional) construct that matches a plus between two integer constants. 
    * (SUCH A RULE SHOULD NOT BE  PART OF YOUR PARSER):
    
    plus_consts	: INT_CONST '+' INT_CONST 
    
    * where INT_CONST is a terminal for an integer constant. Now, a correct
    * action for this rule that attaches the correct line number to plus_const
    * would look like the following:
    
    plus_consts	: INT_CONST '+' INT_CONST 
    {
      // Set the line number of the current non-terminal:
      // ***********************************************
      // You can access the line numbers of the i'th item with @i, just
      // like you acess the value of the i'th expression with $i.
      //
      // Here, we choose the line number of the last INT_CONST (@3) as the
      // line number of the resulting expression (@$). You are free to pick
      // any reasonable line as the line number of non-terminals. If you 
      // omit the statement @$=..., bison has default rules for deciding which 
      // line number to use. Check the manual for details if you are interested.
      @$ = @3;
      
      
      // Observe that we call SET_NODELOC(@3); this will set the global variable
      // node_lineno to @3. Since the constructor call "plus" uses the value of 
      // this global, the plus node will now have the correct line number.
      SET_NODELOC(@3);
      
      // construct the result node:
      $$ = plus(int_const($1), int_const($3));
    }
    
    */
    
    
    
    void yyerror(const char *s);        /*  defined below; called for each parse error */
    extern int yylex();           /*  the entry point to the lexer  */
    
    /************************************************************************/
    /*                DONT CHANGE ANYTHING IN THIS SECTION                  */
    
    Program ast_root;	      /* the result of the parse  */
    Classes parse_results;        /* for use in semantic analysis */
    int omerrs = 0;               /* number of errors in lexing and parsing */
    %}

    /* A union of all the types that can be the result of parsing actions. */
    %union {
      Boolean boolean;
      Symbol symbol;
      Program program;
      Class_ class_;
      Classes classes;
      Feature feature;
      Features features;
      Formal formal;
      Formals formals;
      Case case_;
      Cases cases;
      Expression expression;
      Expressions expressions;
      char *error_msg;
    }
    
    /* 
    Declare the terminals; a few have types for associated lexemes.
    The token ERROR is never used in the parser; thus, it is a parse
    error when the lexer returns it.
    
    The integer following token declaration is the numeric constant used
    to represent that token internally.  Typically, Bison generates these
    on its own, but we give explicit numbers to prevent version parity
    problems (bison 1.25 and earlier start at 258, later versions -- at
    257)
    */
    %token CLASS 258 ELSE 259 FI 260 IF 261 IN 262 
    %token INHERITS 263 LET 264 LOOP 265 POOL 266 THEN 267 WHILE 268
    %token CASE 269 ESAC 270 OF 271 DARROW 272 NEW 273 ISVOID 274
    %token <symbol>  STR_CONST 275 INT_CONST 276 
    %token <boolean> BOOL_CONST 277
    %token <symbol>  TYPEID 278 OBJECTID 279 
    %token ASSIGN 280 NOT 281 LE 282 ERROR 283
    
    /*  DON'T CHANGE ANYTHING ABOVE THIS LINE, OR YOUR PARSER WONT WORK       */
    /**************************************************************************/

    /* %define parse.error detailed */
    
    /* Complete the nonterminal list below, giving a type for the semantic
    value of each non terminal. (See section 3.6 in the bison 
    documentation for details). */

    
    /* Declare types for the grammar's non-terminals. */
    %type <program> program
    %type <class_> class
    %type <classes> class_list
    %type <feature> feature attribute method
    %type <features> feature_list feature_list_nonempty
    %type <formal> formal
    %type <formals> formal_list formal_list_nonempty
    %type <expression> expression dispatch static_dispatch let lets math_expression bool_expression
    %type <expressions> expression_list expression_list_nonempty expression_block expression_block_list
    %type <case_> case_
    %type <cases> case_list
      /* Boolean boolean; */
      /* Symbol symbol; */
    
    /* Precedence declarations go here. */
    %right ASSIGN
    %left NOT
    %nonassoc '<' '=' LE
    %left '+' '-'
    %left '*' '/'
    %left ISVOID
    %left '~'
    %left '@'
    %left '.'

    %%

    program: class_list  { @$ = @1; ast_root = program($1); }
           ;
    
    // [[class;]]+
    class_list: class             { $$ = single_Classes($1); parse_results = $$; }
              | error             { $$ = nil_Classes(); }
              | class_list class  { $$ = append_Classes($1, single_Classes($2)); parse_results = $$; }
              ;
    
    // class TYPE [inherits TYPE] { [[feature;]]* }
    class: CLASS TYPEID '{' feature_list '}' ';'                  { $$ = class_($2, idtable.add_string("Object"), $4, stringtable.add_string(curr_filename)); }
         | CLASS TYPEID INHERITS TYPEID '{' feature_list '}' ';'  { $$ = class_($2, $4, $6, stringtable.add_string(curr_filename)); }
         ;

    // [[feature;]]*
    feature_list:                        { $$ = nil_Features(); }
                | feature_list_nonempty  { $$ = $1; }
                ;

    feature_list_nonempty: feature               { $$ = single_Features($1); }
                         | error                 { $$ = nil_Features(); }
                         | feature_list feature  { $$ = append_Features($1, single_Features($2)); }
                         | feature_list error    { $$ = $1; }
                         ;

    //   ID([formal [[, formal]]*]): TYPE { expr }
    // | ID : TYPE [ <- expr ]
    feature: method     { $$ = $1; }
           | attribute  { $$ = $1; }
           ;

    // ID : TYPE [ <- expr ]
    attribute: OBJECTID ':' TYPEID ';'                    { $$ = attr($1, $3, no_expr()); }
             | OBJECTID ':' TYPEID ASSIGN expression ';'  { $$ = attr($1, $3, $5); }
             | error expression ';'                       {}
             ;

    // ID([formal [[, formal]]*]): TYPE { expr }
    method: OBJECTID '(' formal_list ')' ':' TYPEID '{' expression '}' ';'  { $$ = method($1, $3, $6, $8); }
          | OBJECTID '(' formal_list ')' ':' TYPEID '{' error ';'           {}
          | OBJECTID '(' error ')' ':' TYPEID '{' expression ';'            {}
          | OBJECTID '(' error ')' ':' TYPEID '{' error ';'                 {}
          ;

    // [formal [[, formal]]*]
    formal_list:                       { $$ = nil_Formals(); }
               | formal_list_nonempty  { $$ = $1; }
               ;

    // formal [[, formal]]*
    formal_list_nonempty: formal                  { $$ = single_Formals($1); }
                        | formal_list ',' formal  { $$ = append_Formals($1, single_Formals($3)); }
                        ;

    // ID : TYPE
    formal: OBJECTID ':' TYPEID  { $$ = formal($1, $3); }

                // ID <- expr
    expression: OBJECTID ASSIGN expression  { $$ = assign($1, $3); }
                //   expr[@TYPE].ID([expr [[,expr]]*])
                // | ID( [ expr [[, expr]]∗ ] )
              | static_dispatch  { $$ = $1; }
              | dispatch         { $$ = $1; }
                // if expr then expr else expr fi
              | IF expression THEN expression ELSE expression FI  { $$ = cond($2, $4, $6); }
                // while expr loop expr pool
              | WHILE expression LOOP expression POOL  { $$ = loop($2, $4); }
                // { [[expr;]]+ }
              | expression_block  { $$ = block($1); }
                // let ID : TYPE [<- expr] [[, ID : TYPE [<- expr]]]* in expr
              | let
                // case expr of [[ID : TYPE => expr;]]+ esac
              | CASE expression OF case_list ESAC  { $$ = typcase($2, $4); }
                // new TYPE
              | NEW TYPEID  { $$ = new_($2); }
                // isvoid expr
              | ISVOID expression  { $$ = isvoid($2); }
                //   expr + expr
                // | expr - expr
                // | expr * expr
                // | expr / expr
              | math_expression
                //   ~ expr
                // | expr < expr
                // | expr <= expr
                // | expr = expr
              | bool_expression
                // not expr
              | NOT expression  { $$ = comp($2); }
                // (expr)
              | '(' expression ')'  { $$ = $2; }
                // ID
              | OBJECTID  { $$ = object($1); }
                // integer
              | INT_CONST  { $$ = int_const($1); }
                // string
              | STR_CONST  { $$ = string_const($1); }
                //   true
                // | false
              | BOOL_CONST  { $$ = bool_const($1); }
              ;

    //   expr.ID([expr [[, expr]]*])
    // | ID([expr [[, expr]]*])
    dispatch: expression '.' OBJECTID '(' expression_list ')' { $$ = dispatch($1, $3, $5); }
            | OBJECTID '(' expression_list ')'                { $$ = dispatch(object(idtable.add_string("self")), $1, $3); }
            | OBJECTID '(' error ')'                          {}
            ;

    // expr@TYPE.ID([expr [[,expr]]*])
    static_dispatch: expression '@' TYPEID '.' OBJECTID '(' expression_list ')'  { $$ = static_dispatch($1, $3, $5, $7); }
                   | expression '@' TYPEID '.' OBJECTID '(' error ')'            {}
                   ;

    // [expr [[,expr]]*]
    expression_list:                           { $$ = nil_Expressions(); }
                   | expression_list_nonempty  { $$ = $1; }
                   ;

    // expr [[,expr]]*
    expression_list_nonempty: expression                      { $$ = single_Expressions($1); }
                            | expression_list ',' expression  { $$ = append_Expressions($1, single_Expressions($3)); }
                            ;

    // [[expr;]]+
    expression_block: '{' expression_block_list '}'  { $$ = $2; }
                    | '{' error '}'                  {}
                    ;

    expression_block_list: expression ';'                        { $$ = single_Expressions($1); }
                         | error ';'                             { $$ = nil_Expressions(); }
                         | expression_block_list expression ';'  { $$ = append_Expressions($1, single_Expressions($2)); }
                         | expression_block_list error ';'       { $$ = $1; }
                         ;

    // let ID : TYPE [<- expr] [[, ID : TYPE [<- expr]]]* in expr
    // Special handling, since "let A:B, C:D in x" has to be transformed into "let A:B in let C:D in x"
    let: LET OBJECTID ':' TYPEID IN expression                    { $$ = let($2, $4, no_expr(), $6); }
       | LET OBJECTID ':' TYPEID ASSIGN expression IN expression  { $$ = let($2, $4, $6, $8); }
       | LET OBJECTID ':' TYPEID lets                             { $$ = let($2, $4, no_expr(), $5); }
       | LET OBJECTID ':' TYPEID ASSIGN expression lets           { $$ = let($2, $4, $6, $7); }
       | LET OBJECTID ':' TYPEID ASSIGN error lets                { $$ = $7; }
       ;

    lets: ',' OBJECTID ':' TYPEID lets                             { $$ = let($2, $4, no_expr(), $5); }
        | ',' OBJECTID ':' TYPEID ASSIGN expression lets           { $$ = let($2, $4, $6, $7); }
        | ',' OBJECTID ':' TYPEID ASSIGN error lets                { $$ = $7; }
        | ',' OBJECTID ':' TYPEID IN expression                    { $$ = let($2, $4, no_expr(), $6); }
        | ',' OBJECTID ':' TYPEID ASSIGN expression IN expression  { $$ = let($2, $4, $6, $8); }
        ;

    // [[ID : TYPE => expr;]]+
    case_list: case_            { $$ = single_Cases($1); }
             | case_list case_  { $$ = append_Cases($1, single_Cases($2)); }
             ;

    // ID : TYPE => expr;
    case_: OBJECTID ':' TYPEID DARROW expression ';'  { $$ = branch($1, $3, $5); }
         ;

    //   expr + expr
    // | expr - expr
    // | expr * expr
    // | expr / expr
    math_expression: expression '+' expression  { $$ = plus($1, $3); }
                   | expression '-' expression  { $$ = sub($1, $3); }
                   | expression '*' expression  { $$ = mul($1, $3); }
                   | expression '/' expression  { $$ = divide($1, $3); }
                   ;

    //   ~ expr
    // | expr < expr
    // | expr <= expr
    // | expr = expr
    bool_expression: '~' expression  { $$ = neg($2); }
                   | expression '<' expression  { $$ = lt($1, $3); }
                   | expression LE expression  { $$ = leq($1, $3); }
                   | expression '=' expression  { $$ = eq($1, $3); }
                   ;

    /* end of grammar */
    %%
    
    /* This function is called automatically when Bison detects a parse error. */
    void yyerror(const char *s)
    {
      extern int curr_lineno;
      
      cerr << "\"" << curr_filename << "\", line " << curr_lineno << ": " \
      << s << " at or near ";
      print_cool_token(yychar);
      cerr << endl;
      omerrs++;
      
      if(omerrs>50) {fprintf(stdout, "More than 50 errors\n"); exit(1);}
    }